Add image support for tool call results in Anthropic provider

lib/req_llm/providers/anthropic/context.ex

@@ -143,7 +143,7 @@ defmodule ReqLLM.Providers.Anthropic.Context do
         %{
           type: "tool_result",
           tool_use_id: id,
-          content: extract_text_content(content)
+          content: encode_tool_result_content(content)
         }
       ]
     }
@@ -259,6 +259,60 @@ defmodule ReqLLM.Providers.Anthropic.Context do
     thinking_blocks ++ [%{type: "text", text: text_string}] ++ tool_blocks
   end
 
+  # Encode tool result content - supports text and images
+  # Anthropic tool_result content can be a string (text only) or array of content blocks
+  defp encode_tool_result_content(content_parts) when is_list(content_parts) do
+    has_images? =
+      Enum.any?(content_parts, fn
+        %ReqLLM.Message.ContentPart{type: :image} -> true
+        %ReqLLM.Message.ContentPart{type: :image_url} -> true
+        _ -> false
+      end)
+
+    if has_images? do
+      content_parts
+      |> Enum.map(&encode_tool_result_part_as_block/1)
+      |> Enum.reject(&is_nil/1)
+    else
+      extract_text_content(content_parts)
+    end
+  end
+
+  defp encode_tool_result_content(_), do: ""
+
+  defp encode_tool_result_part_as_block(%ReqLLM.Message.ContentPart{type: :text, text: text}) do
+    %{type: "text", text: text}
+  end
+
+  defp encode_tool_result_part_as_block(%ReqLLM.Message.ContentPart{
+         type: :image,
+         data: data,
+         media_type: media_type
+       }) do
+    base64 = Base.encode64(data)
+
+    %{
+      type: "image",
+      source: %{
+        type: "base64",
+        media_type: media_type,
+        data: base64
+      }
+    }
+  end
+
+  defp encode_tool_result_part_as_block(%ReqLLM.Message.ContentPart{type: :image_url, url: url}) do
+    %{
+      type: "image",
+      source: %{
+        type: "url",
+        url: url
+      }
+    }
+  end
+
+  defp encode_tool_result_part_as_block(_), do: nil
+
   defp encode_reasoning_details(nil), do: []
   defp encode_reasoning_details([]), do: []