fisher/build.gradle at master · predictry/fisher · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'war'

sourceCompatibility = 1.8
version = '0.1'

def warFile = 'fisher.war'

war {
    archiveName = warFile
}

repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    // Spring Framework
    compile 'org.springframework:spring-webmvc:4.2.0.RELEASE'
    compile 'org.springframework:spring-aspects:4.2.0.RELEASE'
    compile 'org.springframework:spring-test:4.2.0.RELEASE'
    compile 'org.springframework:spring-jms:4.2.0.RELEASE'

    // Elasticsearch
    compile 'org.elasticsearch:elasticsearch:1.6.0'
    compile 'org.springframework.data:spring-data-elasticsearch:1.2.0.RELEASE'

    // Amazon SDK
    compile 'com.amazonaws:aws-java-sdk-s3:1.10.1'

    // JMS
    compile 'org.apache.activemq:activemq-client:5.11.1'

    // Others
    compile 'com.fasterxml.jackson.core:jackson-databind:2.5.3'
    compile 'com.fasterxml.jackson.core:jackson-core:2.5.3'
    compile 'javax:javaee-web-api:7.0'
    compile 'org.slf4j:slf4j-api:1.7.12'
    compile 'com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.4.0'
    runtime 'org.slf4j:slf4j-log4j12:1.7.12'
    compile 'log4j:log4j:1.2.17'
    compile 'log4j:apache-log4j-extras:1.0'
    testCompile group: 'junit', name: 'junit', version: '4.+'
}

task remoteShutdownTomcat << {
    exec {
        executable "/usr/bin/ssh"
        args "-i", sshPEMFile, sshTargetHost, "'${sshTargetShutdownScript}'"
    }
}

task remoteStartTomcat << {
    exec {
        executable "/usr/bin/ssh"
        args "-i", sshPEMFile, sshTargetHost, "'${sshTargetStartupScript}'"
    }
}

task remoteDeploy(dependsOn: ['build','remoteShutdownTomcat']) << {
    // Copy War file
    exec {
        executable "/usr/bin/scp"
        args "-i", sshPEMFile, "${buildDir}/libs/${warFile}",
            "${sshTargetHost}:${sshTargetTomcatWebapp}/${warFile}"
    }
}

task testDomainClass(type: Test, dependsOn: testClasses) {
    include 'com/predictry/fisher/domain/**'
}