dakko/flake.nix at master · nullishamy/dakko · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
  };

  outputs =
    {
      self,
      nixpkgs,
      rust-overlay,
      ...
    }:
    let
      systems = [
        "aarch64-darwin"
        "aarch64-linux"
        "x86_64-darwin"
        "x86_64-linux"
      ];

      forEachSystem =
        function:
        nixpkgs.lib.genAttrs systems (
          system:
          let
            overlays = [ (import rust-overlay) ];
            pkgs = import nixpkgs { inherit system overlays; };
          in
          function { inherit system pkgs; }
        );
    in
    {
      devShells = forEachSystem (
        { pkgs, ... }:
        {
          default =
            let
              libraries = with pkgs; [
                webkitgtk
                gtk3
                cairo
                gdk-pixbuf
                glib
                dbus
                openssl_3
                librsvg
              ];

              packages = with pkgs; [
                curl
                wget
                pkg-config
                dbus
                openssl_3
                glib
                gtk3
                libsoup
                webkitgtk
                librsvg
              ];
            in
            pkgs.mkShell {
              env = {
                LD_LIBRARY_PATH = "${pkgs.lib.makeLibraryPath libraries}:$LD_LIBRARY_PATH";
                XDG_DATA_DIRS = "${pkgs.gsettings-desktop-schemas}/share/gsettings-schemas/${pkgs.gsettings-desktop-schemas.name}:${pkgs.gtk3}/share/gsettings-schemas/${pkgs.gtk3.name}:$XDG_DATA_DIRS";
                GIO_MODULE_DIR = "${pkgs.glib-networking}/lib/gio/modules/";
              };

              packages =
                with pkgs;
                [
                  nodejs_20
                  nodePackages.yarn
                  (rust-bin.stable.latest.default.override {
                    extensions = [
                      "rust-src"
                      "rust-analyzer"
                      "clippy"
                    ];
                  })
                ]
                ++ packages;
            };
        }
      );

      formatter = forEachSystem ({ pkgs, ... }: pkgs.nixfmt-rfc-style);

      packages = forEachSystem (
        { pkgs, system }:
        {
          dakko = pkgs.callPackage ./package.nix { };
          default = self.packages.${system}.dakko;
        }
      );
    };
}