nix-binary-ninja/flake.nix at master · jchv/nix-binary-ninja · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
{
  description = "Flake for building Binary Ninja";

  inputs = {
    nixpkgs.url = "https://channels.nixos.org/nixos-unstable/nixexprs.tar.zst";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    inputs@{
      self,
      nixpkgs,
      flake-utils,
    }:
    let
      mkPackages =
        pkgs:
        let
          lib = nixpkgs.lib;
          sources = import ./sources.nix {
            inherit lib;
            inherit (pkgs) fetchurl requireFile;
          };
          variants = {
            system-qt = { };
            bundled-qt = {
              useSystemQt = false;
            };
            bundled-qt-fhs = {
              useSystemQt = false;
              useFHS = true;
            };
          };
          sets = lib.mapAttrs (
            _: args:
            let
              editions = lib.mapAttrs (
                binaryNinjaEdition: _: pkgs.callPackage ./package.nix (args // { inherit binaryNinjaEdition; })
              ) sources.editions;
            in
            editions
            // lib.mapAttrs' (
              name: package: lib.nameValuePair "${name}-wayland" (package.override { forceWayland = true; })
            ) editions
          ) variants;
          flat = lib.concatMapAttrs (
            variant: editions:
            lib.mapAttrs' (
              edition: package: lib.nameValuePair "binary-ninja-${edition}-${variant}" package
            ) editions
          ) sets;
          aliases = lib.mapAttrs' (
            edition: package: lib.nameValuePair "binary-ninja-${edition}" package
          ) sets.system-qt;
        in
        {
          inherit sets;
          packages = flat // aliases;
        };
    in
    flake-utils.lib.eachSystem [ "x86_64-linux" "aarch64-linux" ] (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        sources = pkgs.callPackage ./sources.nix { };
        variants = mkPackages pkgs;
      in
      {
        inherit (sources) version;
        checks = pkgs.lib.mapAttrs' (
          variant: editions:
          pkgs.lib.nameValuePair "simple-${variant}" (
            pkgs.callPackage ./tests/simple-nixos.nix {
              inherit self;
              package = editions.free;
            }
          )
        ) variants.sets;
        legacyPackages.binary-ninja = variants.sets;
        packages = variants.packages // {
          default = variants.packages.binary-ninja-free;
        };
      }
    )
    // {
      overlays.default =
        final: prev:
        let
          variants = mkPackages final;
        in
        variants.packages // { binary-ninja = variants.sets; };
      nixosModules.binaryninja = import ./module.nix inputs;
      darwinModules.binaryninja = import ./module.nix inputs;
      hmModules.binaryninja = import ./hm-module.nix inputs;
    };
}