simulator-nixos/flake.nix at main · c-base/simulator-nixos · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
    nixpkgs-unstable.url = "github:NixOS/nixpkgs/nixos-unstable";
    nixpkgs-xr.url = "github:nix-community/nixpkgs-xr";
    home-manager = {
      url = "github:nix-community/home-manager/release-25.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    overte.url = "github:overte-org/overte";
  };
  outputs =
    {
      self,
      nixpkgs,
      nixpkgs-unstable,
      nixpkgs-xr,
      home-manager,
      overte,
    }@inputs:
    let
      eachSystem =
        f: nixpkgs.lib.attrsets.genAttrs [ "x86_64-linux" ] (system: f nixpkgs.legacyPackages.${system});
    in
    {
      packages = eachSystem (pkgs: {
        overte-vr-appimage = pkgs.callPackage ./packages/overte-vr-appimage.nix { };
        overte-vr = inputs.overte.packages.${pkgs.stdenv.hostPlatform.system}.default;
      });
      nixosConfigurations = {
        simulator =
          let
            system = "x86_64-linux";

            allowedUnfree = [
              "steam"
              "steam-unwrapped"
            ];
            allowedInsecure = [
              #"qtwebengine-5.15.19"
            ];
          in
          nixpkgs.lib.nixosSystem {
            specialArgs = {
              selfpkgs = self.packages.${system};
            };
            modules = [
              (
                { lib, ... }:
                {
                  nix.registry.n.flake = nixpkgs;
                  nixpkgs = {
                    hostPlatform = system;
                    config.allowUnfreePredicate = pkg: builtins.elem (lib.getName pkg) allowedUnfree;
                    config.permittedInsecurePackages = allowedInsecure;
                  };
                  _module.args = {
                    selfpkgs = self.packages.${system};
                    nixpkgs-unstable = import nixpkgs-unstable {
                      inherit system;
                      config.allowUnfreePredicate = pkg: builtins.elem (lib.getName pkg) allowedUnfree;
                      config.permittedInsecurePackages = allowedInsecure;
                      overlays = [
                        inputs.nixpkgs-xr.overlays.default
                      ];
                    };
                    inherit inputs;
                  };
                  home-manager.useGlobalPkgs = true;
                  home-manager.useUserPackages = true;
                  home-manager.backupFileExtension = "hm-bak";
                  home-manager.users.alien.home.stateVersion = "25.11";
                }
              )
              nixpkgs-xr.nixosModules.nixpkgs-xr
              inputs.home-manager.nixosModules.home-manager
              ./machines/simulator/config.nix
            ];
          };
      };
    };
}