devops-framework/build.gradle.kts at master · bkdevops-projects/devops-framework · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79

import org.gradle.api.publish.maven.MavenPublication
import org.gradle.api.publish.maven.tasks.PublishToMavenRepository
import org.gradle.plugins.signing.Sign


description = "Tencent BlueKing DevOps Framework Build"

plugins {
    kotlin("jvm") version Versions.Kotlin apply false
    kotlin("kapt") version Versions.Kotlin apply false
    kotlin("plugin.spring") version Versions.Kotlin apply false
    id("io.spring.dependency-management") version Versions.DependencyManagement apply false
    id("com.tencent.devops.release") version Versions.DevopsReleasePlugin
    id("com.tencent.devops.publish") version Versions.DevopsReleasePlugin
}

val projectVersion = rootProject.file("version.txt").readText().trim()

allprojects {
    group = "com.tencent.devops"
    version = projectVersion

    apply(plugin = "com.tencent.devops.publish")

    repositories {
        mavenCentral()
        gradlePluginPortal()
    }

    tasks.withType<PublishToMavenRepository>().configureEach {
        dependsOn(tasks.withType(Sign::class.java))
    }

    publishing {
        publications {
            withType<MavenPublication> {
                pom {
                    name.set(project.name)
                    description.set(project.description ?: project.name)
                    url.set("https://github.com/bkdevops-projects/devops-framework")
                    licenses {
                        license {
                            name.set("The MIT License (MIT)")
                            url.set("https://opensource.org/licenses/MIT")
                        }
                    }
                    organization {
                        name.set("Tencent BK-CI")
                        url.set("https://github.com/Tencent/bk-ci")
                    }
                    developers {
                        developer {
                            name.set("blueking")
                            email.set("contactus_bk@tencent.com")
                            url.set("https://github.com/TencentBlueKing")
                            roles.set(listOf("Java Developer"))
                        }
                    }
                    scm {
                        connection.set("scm:git:git://github.com/bkdevops-projects/devops-framework.git")
                        developerConnection.set("scm:git:ssh://github.com/bkdevops-projects/devops-framework.git")
                        url.set("https://github.com/bkdevops-projects/devops-framework")
                    }
                }

            }
        }
    }
}

subprojects {
    apply(plugin = "ktlint")
}

release {
    scmUrl.set("scm:git:https://github.com/bkdevops-projects/devops-framework.git")
    incrementPolicy.set("PATCH")
}