CodePlanGUI/build.gradle at master · TuYv/CodePlanGUI · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
plugins {
    id 'java'
    id 'org.jetbrains.kotlin.jvm' version '1.9.25'
    id 'org.jetbrains.kotlin.plugin.serialization' version '1.9.25'
    id 'org.jetbrains.intellij.platform' version '2.1.0'
}

group = 'com.github.codeplangui'
version = pluginVersion

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

kotlin {
    jvmToolchain(17)
}

repositories {
    mavenCentral()
    intellijPlatform {
        defaultRepositories()
    }
}

dependencies {
    intellijPlatform {
        intellijIdeaCommunity(ideaVersion)
        jetbrainsRuntime()
        instrumentationTools()
        pluginVerifier()
        bundledPlugin('Git4Idea')
    }

    implementation 'com.squareup.okhttp3:okhttp:4.12.0'
    implementation 'com.squareup.okhttp3:okhttp-sse:4.12.0'
    implementation 'org.jetbrains.kotlinx:kotlinx-serialization-json:1.6.3'

    testImplementation 'org.junit.jupiter:junit-jupiter:5.10.2'
    testImplementation 'io.mockk:mockk:1.13.10'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

test {
    useJUnitPlatform()
}

tasks.register('installWebviewDependencies', Exec) {
    workingDir 'webview'
    commandLine 'npm', 'ci'
    inputs.file('webview/package.json')
    inputs.file('webview/package-lock.json')
    outputs.dir('webview/node_modules')
}

tasks.register('buildWebview', Exec) {
    dependsOn 'installWebviewDependencies'
    workingDir 'webview'
    commandLine 'npm', 'run', 'build'
    inputs.file('webview/index.html')
    inputs.dir('webview/src')
    inputs.file('webview/package.json')
    inputs.file('webview/package-lock.json')
    inputs.file('webview/vite.config.ts')
    outputs.file('src/main/resources/webview/index.html')
}

tasks.named('processResources').configure {
    dependsOn 'buildWebview'
}

intellijPlatform {
    pluginConfiguration {
        name = 'CodePlanGUI'
        version = pluginVersion
        ideaVersion {
            sinceBuild = '231'
            untilBuild = provider { null }
        }
    }
}