swls/flake.nix at main · SemanticWebLanguageServer/swls · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
{

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs";
    systems.url = "github:nix-systems/default";
    crane.url = "github:ipetkov/crane";

    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };

  };

  outputs =
    {
      self,
      nixpkgs,
      systems,
      crane,
      rust-overlay,
    }:
    let
      eachSystem =
        f:
        nixpkgs.lib.genAttrs (import systems) (
          system:
          let
            pkgs = import nixpkgs {
              inherit system;
              overlays = [ (import rust-overlay) ];
            };

            craneLib = (crane.mkLib pkgs).overrideToolchain (pkgs: pkgs.rust-bin.stable."1.88.0".default);

            self' = self // {
              packages = self.packages.${system} or { };
              devShells = self.devShells.${system} or { };
              checks = self.checks.${system} or { };
              apps = self.apps.${system} or { };
              formatter = self.formatter.${system};
            };
          in
          f {
            inherit
              system
              pkgs
              craneLib
              self'
              ;
          }
        );

      workspace.root = ./.;
      workspace.name = "swls";
      workspace.version = self.sourceInfo.shortRev or self.sourceInfo.lastModifiedDate;
    in
    {
      packages = eachSystem (
        {
          craneLib,
          self',
          ...
        }:
        let
          inherit (self'.packages) swls;

          cargoArtifacts = craneLib.callPackage ./nix-support/cargo-artifacts.nix { inherit workspace; };
        in
        {
          default = swls;

          swls = craneLib.callPackage ./nix-support/workspace-member-package.nix {
            inherit workspace cargoArtifacts;
            member = ./swls;
          };

          lsp-web = craneLib.callPackage ./nix-support/workspace-member-package.nix {
            inherit workspace cargoArtifacts;
            member = ./lsp-web;
          };
        }
      );

      formatter = eachSystem ({ pkgs, ... }: pkgs.nixfmt-rfc-style);

      devShells = eachSystem (
        {
          craneLib,
          self',
          pkgs,
          ...
        }:
        {

          default = craneLib.devShell {
            pname = "${workspace.name}-dev";
            inputsFrom = pkgs.lib.unique (builtins.attrValues self'.packages);
            packages = [
              pkgs.rust-analyzer
              pkgs.taplo
              pkgs.nixd
              self'.formatter
            ];
          };
        }
      );

    };

}