Delphi-Mocks/Delphi.Mocks.InterfaceProxy.pas at master · RenanFragatte/Delphi-Mocks · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
{***************************************************************************}
{                                                                           }
{           Delphi.Mocks                                                    }
{                                                                           }
{           Copyright (C) 2011 Vincent Parrett                              }
{                                                                           }
{           http://www.finalbuilder.com                                     }
{                                                                           }
{                                                                           }
{***************************************************************************}
{                                                                           }
{  Licensed under the Apache License, Version 2.0 (the "License");          }
{  you may not use this file except in compliance with the License.         }
{  You may obtain a copy of the License at                                  }
{                                                                           }
{      http://www.apache.org/licenses/LICENSE-2.0                           }
{                                                                           }
{  Unless required by applicable law or agreed to in writing, software      }
{  distributed under the License is distributed on an "AS IS" BASIS,        }
{  WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. }
{  See the License for the specific language governing permissions and      }
{  limitations under the License.                                           }
{                                                                           }
{***************************************************************************}

unit Delphi.Mocks.InterfaceProxy;

interface

uses
  Rtti,
  SysUtils,
  Delphi.Mocks,
  Delphi.Mocks.Interfaces,
//  Delphi.Mocks.VirtualInterface,
  Delphi.Mocks.ProxyBase;

type
  TProxyBaseInvokeEvent = procedure (Method: TRttiMethod; const Args: TArray<TValue>; out Result: TValue) of object;

  TSetupMode = (None,Behavior,Expectation);

  TInterfaceProxy<T> = class(TBaseProxy<T>)
  private type
   TProxyVirtualInterface = class(TVirtualInterface)
    private
      FProxy : TInterfaceProxy<T>;
    protected
    public
      function QueryInterface(const IID: TGUID; out Obj): HRESULT; override; stdcall;
      constructor Create(AProxy : TInterfaceProxy<T>; AInterface: Pointer; InvokeEvent: TVirtualInterfaceInvokeEvent);
    end;
  private
    FVirtualInterface : IInterface;
  protected
    function InternalQueryInterface(const IID: TGUID; out Obj): HRESULT; stdcall;
    function QueryInterface(const IID: TGUID; out Obj): HRESULT; override;
    function Proxy : T;override;
  public
    constructor Create;override;
    destructor Destroy;override;
  end;


implementation

uses
  TypInfo;

{ TInterfaceProxy<T> }

constructor TInterfaceProxy<T>.Create;
begin
  inherited;
  FVirtualInterface := TProxyVirtualInterface.Create(Self,TypeInfo(T),Self.DoInvoke);
end;

destructor TInterfaceProxy<T>.Destroy;
begin
  FVirtualInterface := nil;
  inherited;
end;

function TInterfaceProxy<T>.InternalQueryInterface(const IID: TGUID; out Obj): HRESULT;
begin
  Result := E_NOINTERFACE;
  if (IsEqualGUID(IID,IInterface)) then
    if GetInterface(IID, Obj) then
      Result := 0;
end;

function TInterfaceProxy<T>.Proxy: T;
var
  pInfo : PTypeInfo;
begin
  pInfo := TypeInfo(T);
  if FVirtualInterface.QueryInterface(GetTypeData(pInfo).Guid,result) <> 0 then
    raise EMockNoProxyException.Create('Error casting to interface ' + string(pInfo.Name) + ' , proxy does not appear to implememnt T');
end;

function TInterfaceProxy<T>.QueryInterface(const IID: TGUID; out Obj): HRESULT;
begin
  Result := E_NOINTERFACE;
  if (FVirtualInterface <> nil) then
    Result := FVirtualInterface.QueryInterface(IID, Obj);
  if result <> 0 then
    Result := inherited;

end;

{ TInterfaceProxy<T>.TProxyVirtualInterface }

constructor TInterfaceProxy<T>.TProxyVirtualInterface.Create(
  AProxy: TInterfaceProxy<T>; AInterface: Pointer;
  InvokeEvent: TVirtualInterfaceInvokeEvent);
begin
  FProxy := AProxy;
  inherited Create(Ainterface,InvokeEvent);
end;


function TInterfaceProxy<T>.TProxyVirtualInterface.QueryInterface(const IID: TGUID; out Obj): HRESULT;
begin
  Result := inherited;
  if Result <> 0 then
    Result := FProxy.InternalQueryInterface(IID, Obj);
end;


end.