thoth/build.gradle at master · MAIF/thoth · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
plugins {
    id 'net.researchgate.release' version '3.0.0'
    id 'java'
    id  'maven-publish'
    id 'signing'
    id("io.github.gradle-nexus.publish-plugin") version "1.3.0"
}
group = 'fr.maif'

subprojects {
    apply plugin: 'java'
    apply plugin: 'signing'
    apply plugin: 'maven-publish'

    group = 'fr.maif'

    repositories {
        mavenCentral()
    }

    java {
        withSourcesJar()
        withJavadocJar()
        toolchain {
            languageVersion = JavaLanguageVersion.of(21)
        }
    }

    ext {
        lombokVersion         = "1.18.44"
        scalaVersion          = "2.13"
        pekkoKafkaVersion     = "1.1.0"
        jacksonVersion        = "3.1.0"
        pekkoVersion          = "1.4.0"
        vavrVersion           = "1.0.1"
        vavrJacksonVersion    = "1.0.0"
        jooqVersion           = "3.21.1"
        jooqAsyncVersion      = "3.0.0-RC1"
        functionalJsonVersion = "2.0.0-RC1"
        kafkaVersion          = "3.9.2"
        reactorKafkaVersion   = "1.3.23"
        reactorVersion        = "3.8.4"
        vertxSqlVersion       = "5.0.10"
        testContainerVersion  = "1.21.1"
        jupiterVersion        = "6.0.3"
        assertJVersion        = "3.27.7"
        mockitoCoreVersion    = "5.18.0"
    }

    test {
        testLogging {
            events "PASSED", "SKIPPED", "FAILED", "STANDARD_OUT", "STANDARD_ERROR"
        }
    }

    publishing {
        publications {
            mavenJava(MavenPublication) {
                from components.java
                pom {
                    name = "Thoth"
                    description = "Reactive event sourcing with java"
                    inceptionYear = "2020"
                    url = "https://github.com/maif/thoth"
                    licenses {
                        license {
                            name = "The Apache License, Version 2.0"
                            url = "http://www.apache.org/licenses/LICENSE-2.0.txt"
                            distribution = "http://www.apache.org/licenses/LICENSE-2.0.txt"
                        }
                    }
                    developers {
                        developer {
                            id = 'alexandre.delegue'
                            name = 'Alexandre Delègue'
                            url = 'https://github.com/larousso'
                        }
                        developer {
                            id = 'benjamin.cavy'
                            name = 'Benjamin Cavy'
                            url = 'https://github.com/ptitFicus'
                        }
                    }
                    scm {
                        url = "https://github.com/maif/thoth"
                        connection = "scm:git:git://github.com/maif/thoth.git"
                        developerConnection = "scm:git:ssh://github.com/maif/thoth.git"
                    }
                }
            }
        }
        signing {
            sign publishing.publications.mavenJava
        }
    }

}

nexusPublishing {
    repositories {
        sonatype {
            nexusUrl.set(uri("https://ossrh-staging-api.central.sonatype.com/service/local/"))
            snapshotRepositoryUrl.set(uri("https://central.sonatype.com/repository/maven-snapshots/"))
            username = System.env.SONATYPE_USERNAME
            password = System.env.SONATYPE_PASSWORD
        }
    }
}


release {
    tagTemplate = 'v${version}'
}
release.git.requireBranch.set('master')