synapse/build.gradle at main · IamCoder18/synapse · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
plugins {
    id 'java-library'
    id 'maven-publish'
    id 'signing'
}

group = 'com.aaravlabs'
version = '0.4.0'

java {
    sourceCompatibility = JavaVersion.VERSION_11
    targetCompatibility = JavaVersion.VERSION_11
    withSourcesJar()
    withJavadocJar()
}

repositories {
    mavenCentral()
}

dependencies {
    compileOnly files('libs/ftc-sdk-stub.jar')
    testCompileOnly files('libs/ftc-sdk-stub.jar')
    testRuntimeOnly files('libs/ftc-sdk-stub.jar')

    testImplementation 'org.junit.jupiter:junit-jupiter-api:5.10.2'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine:5.10.2'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher:1.10.2'
}

test {
    useJUnitPlatform()
}

publishing {
    publications {
        maven(MavenPublication) {
            from components.java
            pom {
                name = 'Synapse'
                description = 'Annotation-driven pub/sub bus for FTC robot code with hardware-thread safety.'
                url = 'https://github.com/IamCoder18/synapse'
                licenses {
                    license {
                        name = 'MIT'
                        url = 'https://opensource.org/licenses/MIT'
                    }
                }
                scm {
                    url = 'https://github.com/IamCoder18/synapse'
                    connection = 'scm:git:git://github.com/IamCoder18/synapse.git'
                    developerConnection = 'scm:git:ssh://git@github.com/IamCoder18/synapse.git'
                }
                developers {
                    developer {
                        id = 'IamCoder18'
                        name = 'IamCoder18'
                    }
                }
            }
        }
    }
    repositories {
        mavenLocal()
        maven {
            name = 'GitHubPackages'
            url = 'https://maven.pkg.github.com/IamCoder18/synapse'
            credentials {
                username = project.findProperty('gpr.user') ?: System.getenv('GITHUB_USER') ?: System.getenv('GITHUB_ACTOR')
                password = project.findProperty('gpr.key') ?: System.getenv('GITHUB_TOKEN')
            }
        }
    }
}

signing {
    def signingKey = findProperty('signing.key') ?: System.getenv('SIGNING_KEY')
    def signingPassphrase = findProperty('signing.password') ?: System.getenv('SIGNING_PASSWORD')
    if (signingKey && signingPassphrase) {
        useInMemoryPgpKeys(signingKey, signingPassphrase)
        sign publishing.publications.maven
    }
}